登录/ 注册
 找回密码
 立即注册
关闭

CSDN热搜

程序园 精品问答 技术交流 资源下载
返回列表 发新帖
首页 › 业界区 › 业界 ›Jenkins-Pipline实现原理

Jenkins-Pipline实现原理

扔飒 前天 20:08
Jenkins-Pipline原理

本文仅探讨jenkins pipline 的原理，是流水线的一个demo版本实现，不能代表Jenkins pipline的具体实现，仅供参考。
1. Jenkins流水线介绍

Jenkinsfile流水线是Jenkins CI/CD工具中用来定义、构建和管理软件交付流程的一种声明式文件。
它允许将整个软件交付流程以代码的形式进行描述，从而实现对软件交付过程的可追踪性、可维护性和可扩展性。
Jenkinsfile使用一种基于Groovy的DSL（领域特定语言）来定义流水线，开发人员可以通过编写Groovy代码来描述流水线的结构和逻辑。
简而言之：Jenkinsfile 就是 Groovy脚本。
2. Groovy实现DSL的基础

Groovy是一种基于JVM的动态语言，它可以直接使用Java类和库，也可以通过闭包和元编程等特性来实现DSL。
2.1 方法调用

在Groovy中，通常情况下需要使用括号来调用带有参数的方法。但是，在一些特定的情况下，也可以省略括号来调用方法，并将参数作为闭包的一部分传递。
  1. def greet(String name) {
  2.     println("Hello, $name!")
  3. }
  5. // 使用括号调用方法
  6. greet("Alice")  // 输出: Hello, Alice!
  8. // 省略括号，将参数作为闭包的一部分传递
  9. greet "Bob"    // 输出: Hello, Bob!
复制代码
2.2 闭包

闭包可以被视为一个可调用的代码块，它可以作为参数传递给方法、赋值给变量，以及作为返回值返回。

  • 定义闭包：可以使用{}大括号来定义一个闭包，并在其中编写代码块。例如：
  1. def closure = { param ->
  2.     println("Hello, $param!")
  3. }
复制代码

  • 参数传递：闭包可以接受零个或多个参数，并在代码块中使用这些参数。例如：
  1. def printSum = { a, b ->
  2.     println(a + b)
  3. }
复制代码

  • 调用闭包：可以通过将闭包像函数一样进行调用来执行其中的代码块。例如：
  1. closure("Alice")  // 输出: Hello, Alice!
  3. printSum(3, 5)   // 输出: 8
复制代码

  • 作为参数传递：闭包可以作为参数传递给其他方法，使得方法具有更高的灵活性和可重用性。例如：
  1. def processData(data, closure) {
  2. // 执行某些逻辑...
  3.     closure(data)
  4. }
  6. processData("Hello", { input ->
  7.     println("Received: $input")
  8. })
复制代码
2.3 闭包代理

Groovy还提供了闭包代理（Closure Delegate）机制。闭包代理允许在闭包中访问外部对象的成员变量和方法，而无需显式地使用点操作符。
以下是一个示例：
  1. class Person {
  2.     String name
  4.     void sayHello() {
  5.         println("Hello, I'm $name")
  6.     }
  7. }
  9. def person = new Person(name: "Alice")
  10. def closure = { sayHello() }  // 使用闭包代理调用Person对象的sayHello方法
  11. closure.delegate = person
  12. closure()  // 输出: Hello, I'm Alice
复制代码
在上面的例子中，我们定义了一个名为closure的闭包，其中调用了外部的Person对象的sayHello()方法。
通过将闭包的delegate属性设置为person对象，我们实现了在闭包中调用person.sayHello()的效果。
3. 从零实现DSL&Jenkinsfile

3.1 使用DSL编写流水线

实现的流水线如下：
jenkinsfile.groovy
  1. import static Dsl.pipeline
  3. pipeline {
  4.     agent any
  6.     environment {
  7.         SOME_NUMBER = 123
  8.         SOME_STRING = "foobar"
  9.     }
  11.     stages {
  12.         stage("Build") {
  13.             steps { env ->
  14.                 sh "ls -la"
  15.                 sh(script: 'date +%Y-%m-%d', returnStdout: false)
  16.                 echo "Groovy rocks!"
  17.                 echo "env.SOME_STRING = ${env.SOME_STRING}"
  18.             }
  19.         }
  20.         stage("Test") {
  21.             steps {
  22.                 sh """
  23.                     echo "Testing..."
  24.                     """
  25.             }
  26.         }
  27.     }
  28. }
复制代码
3.2 DSL的具体实现

DSL实现代码如下：
Dsl.groovy
  1. import groovy.transform.NamedParam
  2. import groovy.transform.NamedParams
  3. import groovy.transform.stc.ClosureParams
  4. import groovy.transform.stc.SimpleType
  6. import java.util.concurrent.ConcurrentHashMap
  7. import java.util.concurrent.ConcurrentMap
  9. import static groovy.lang.Closure.DELEGATE_FIRST
  10. import static groovy.lang.Closure.DELEGATE_ONLY
  12. class Dsl {
  14.     static void pipeline(@DelegatesTo(value = PipelineDsl, strategy = DELEGATE_ONLY) final Closure closure) {
  15.         final PipelineDsl dsl = new PipelineDsl()
  17.         closure.delegate = dsl
  18.         closure.resolveStrategy = DELEGATE_ONLY
  19.         closure.call()
  20.     }
  22. }
  24. class PipelineDsl {
  25.     // 定义一个占位符常量
  26.     final Placeholder any = Placeholder.ANY
  28.     // 使用 ConcurrentHashMap 创建环境变量的并发映射
  29.     static final ConcurrentMap<String, String> env = [:] as ConcurrentHashMap
  31.     // 定义 agent 方法
  32.     void agent(final Placeholder any) {
  33.         println "Running pipeline using any available agent..."
  34.     }
  36.     // 定义 environment 方法
  37.     void environment(@DelegatesTo(value = Map, strategy = DELEGATE_FIRST) final Closure closure) {
  38.         // 将闭包委托给 env 并执行闭包
  39.         env.with(closure)
  40.     }
  42.     // 定义 stages 方法
  43.     void stages(@DelegatesTo(value = StagesDsl, strategy = DELEGATE_ONLY) final Closure closure) {
  44.         final StagesDsl dsl = new StagesDsl()
  46.         closure.delegate = dsl
  47.         closure.resolveStrategy = DELEGATE_ONLY
  48.         closure.call()
  50.         // 遍历 stages 列表并依次运行每个 stage
  51.         dsl.stages.each { stage ->
  52.             stage.run()
  53.         }
  54.     }
  56.     // 定义占位符枚举类
  57.     enum Placeholder {
  58.         ANY
  59.     }
  60. }
  62. class StagesDsl {
  63.     // 定义 stages 列表
  64.     protected final List<Stage> stages = []
  66.     // 定义 stage 方法
  67.     void stage(final String name, @DelegatesTo(value = StageDsl, strategy = DELEGATE_ONLY) final Closure closure) {
  68.         // 将 stage 添加到 stages 列表中
  69.         stages << new Stage(name, closure)
  70.     }
  71. }
  73. class Stage {
  74.     final String name
  75.     final Closure closure
  77.     // 定义 Stage 类的构造函数
  78.     Stage(String name, Closure closure) {
  79.         this.name = name
  80.         this.closure = closure
  81.     }
  83.     // 运行 stage 的方法
  84.     void run() {
  85.         println "==> Running '${name}' stage..."
  87.         final StageDsl dsl = new StageDsl()
  89.         closure.delegate = dsl
  90.         closure.resolveStrategy = DELEGATE_ONLY
  91.         closure.call()
  92.     }
  93. }
  95. class StageDsl {
  96.     // 定义 steps 方法
  97.     void steps(
  98.             @DelegatesTo(value = Steps, strategy = DELEGATE_ONLY)
  99.             @ClosureParams(value = SimpleType, options = ["java.util.Map"]) final Closure closure) {
  100.         final Steps steps = new Steps()
  102.         closure.delegate = steps
  103.         closure.resolveStrategy = DELEGATE_ONLY
  104.         closure.call(PipelineDsl.env)
  105.     }
  106. }
  108. class Steps {
  109.     // 定义 sh 方法
  110.     void sh(final String script) {
  111.             sh(script: script, returnStdout: false)
  112.     }
  114.     // 定义重载的 sh 方法
  115.     Object sh(@NamedParams([
  116.             @NamedParam(value = "script", type = String, required = true),
  117.             @NamedParam(value = "returnStdout", type = Boolean)
  118.     ]) final Map param) {
  120.         // 执行 shell 脚本，并等待执行完成
  121.         final Process p = param.script.toString().execute()
  122.         p.waitFor()
  124.         println "+ ${param.script}"
  126.         if (p.exitValue() == 0) {
  127.             if (param.returnStdout) {
  128.                 return p.text
  129.             }
  131.             println p.text
  132.         } else {
  133.             println p.err.text
  134.         }
  135.     }
  137.     // 定义 echo 方法
  138.     void echo(final String message) {
  139.         println "[ECHO] ${message}"
  140.     }
  141. }
复制代码
3.4 流水线调用流程分析
  1. $ groovy jenkinsfile.groovy
  3. Running pipeline using any available agent...
  4. ==> Running 'Build' stage...
  5. + ls -la
  6. razem 32
  7. drwxrwxr-x   5 wololock wololock 4096 04-07 18:20 .
  8. drwxrwxr-x. 45 wololock wololock 4096 04-04 12:47 ..
  9. drwxrwxr-x   3 wololock wololock 4096 04-04 12:48 com
  10. drwxrwxr-x   7 wololock wololock 4096 04-07 18:20 .git
  11. -rw-rw-r--   1 wololock wololock   29 04-07 18:19 .gitignore
  12. drwxrwxr-x   2 wololock wololock 4096 04-07 18:19 .idea
  13. -rw-rw-r--   1 wololock wololock 1016 04-04 13:23 jenkinsfile.groovy
  14. -rw-rw-r--   1 wololock wololock   23 04-07 18:20 README.md
  16. + date +%Y-%m-%d
  17. 2020-04-07
  19. [ECHO] Groovy rocks!
  20. [ECHO] env.SOME_STRING = foobar
  21. ==> Running 'Test' stage...
  22. + mvn -version
  23. Apache Maven 3.5.4 (1edded0938998edf8bf061f1ceb3cfdeccf443fe; 2018-06-17T20:33:14+02:00)
  24. Maven home: /home/wololock/.sdkman/candidates/maven/current
  25. Java version: 1.8.0_232, vendor: Oracle Corporation, runtime: /home/wololock/.sdkman/candidates/java/8.0.232-open/jre
  26. Default locale: pl_PL, platform encoding: UTF-8
  27. OS name: "linux", version: "5.5.10-100.fc30.x86_64", arch: "amd64", family: "unix"
复制代码
The end.
参考资料:

Groovy DSL Quickstart:
https://github.com/wololock/groovy-dsl-quickstart

来源：程序园用户自行投稿发布，如果侵权，请联系站长删除
免责声明：如果侵犯了您的权益，请联系站长，我们会及时删除侵权内容，谢谢合作！

使用道具 举报
相关推荐
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册
发帖
扔飒
前天 20:08

0

粉丝关注

11

主题发布

板块介绍填写区域，请于后台编辑
微信扫一扫